Présentation des mailslots et de leur utilisation en Delphi

Date de publication : 27/06/2004

Par Pierre Castelain
 

Cet article a pour but de présenter les mailslots et leur utilisation en Delphi. Les mailslot représentent un moyen simple de faire communiquer différents processus entre eux.

1. Introduction

• le presse-papier,
• COM,
• les messages Windows (et en particulier le message WM_COPYDATA),
• DDE,
• les fichiers mappés (file mapping),
• les mailslots,
• les pipes (anonymes ou nommés),
• RPC,
• les sockets Windows.

• Ils ne nécessitent qu'un jeu de fonctions très réduit et simple à utiliser.
• Ils permettent de faire communiquer simplement des processus s'exécutant sur différents ordinateurs à travers un réseau.
• Ils intègrent également un mécanisme de diffusion qui permet à un client d'envoyer un message à tous les serveurs d'un domaine en un seul appel.

2. Les adresses

• Une adresse de mailslot commence toujours par un double antislash '\\'
• Vient ensuite le nom de l'emplacement du mailslot. Cet emplacement peut représenter :
• Un ordinateur : nous utiliserons le nom de l'ordinateur dans le réseau.
• Tous les ordinateurs d'un domaine : nous utiliserons le nom du domaine (ou du groupe de travail).
• Tous les ordinateurs du domaine principal : nous utiliserons le caractère étoile '*'.
• L'ordinateur sur lequel le processus s'exécute : nous utiliserons le caractère point '.'.
  Attention : seuls les messages de moins de 425 octets peuvent être envoyés à plusieurs ordinateurs en même temps (broadcast).
• L'emplacement est toujours suivi de la chaîne '\mailslot\' qui indique qu'il ne s'agit pas d'un "vrai" fichier mais bien d'un mailslot.
• La dernière section est constituée d'un certain nombre de répertoires séparés par des antislashs '\' et du nom du mailslot. Cette section est donc construite comme une chemin de fichier classique. Vous pouvez donc classer les mailslots par répertoires si vous en utilisez beaucoup en même temps ou si vous voulez être rigoureux.

• Le mailslot sera créé par le processus serveur avec l'adresse : '\\.\mailslot\TEST'.
• Le mailslot sera ouvert par un client s'exécutant sur la même machine avec l'adresse '\\.\mailslot\TEST'.
• Le mailslot sera ouvert par un client s'exécutant sur une autre machine avec l'adresse '\\SERVEUR\mailslot\TEST'.
• Le mailslot sera ouvert par un client désirant envoyer un message à tous les serveurs du domaine 'DOMAINE' avec l'adresse '\\DOMAINE\mailslot\TEST'.
• Enfin, le mailslot sera ouvert par un client désirant envoyer un message à tous les serveurs du domaine principal avec l'adresse '\\*\mailslot\TEST'.

3. Les fonctions

3.1. CreateMailslot

          function CreateMailslot(lpName: PChar; nMaxMessageSize: DWORD;
            lReadTimeout: DWORD; lpSecurityAttributes: PSecurityAttributes): THandle; stdcall;

• lpName : le nom du mailslot (son adresse),
• nMaxMessageSize : la taille maximale d'un message (0 pour une taille quelconque),
• lReadTimeout : le temps maximal en millisecondes pendant lequel le serveur attendra un nouveau message avant de quitter le processus de lecture. 0 pour un retour immédiat s'il n'y a pas de message et MAILSLOT_WAIT_FOREVER pour une attente infinie.
• lpSecurityAttributes : un pointeur vers une structure de type SECURITY_ATTRIBUTES que nous ignorerons dans cet article. Sachez simplement que si vous voulez partager le mailslot avec un processus enfant du serveur, vous devrez modifier le membre bInheritHandle de cette structure.
• La valeur de retour est un handle (valeur numérique) qui sera utilisé comme argument par les autres fonctions afin d'identifier le mailslot.

          h:= CreateMailslot('\\.\mailslot\MonMailslot', 0, MAILSLOT_WAIT_FOREVER, nil);

3.2. GetMailslotInfo

          function GetMailslotInfo(hMailslot: THandle; lpMaxMessageSize: Pointer;
            var lpNextSize: DWORD; lpMessageCount, lpReadTimeout: Pointer): BOOL; stdcall;

• hMailslot : le handle obtenu par l'appel à CreateMailslot.
• lpMaxMessageSize : pointeur sur un entier qui sera rempli avec la taille maximale d'un message sur ce mailslot (la valeur fournie à la fonction CreateMailslot).
• lpNextSize : variable de type entier qui sera remplie avec la taille du prochain message à lire (MAILSLOT_NO_MESSAGE s'il n'y a pas de message à lire).
• lpMessageCount : pointeur sur un entier qui sera rempli avec le nombre de messages à lire.
• lpReadTimeout : pointeur sur un entier qui sera rempli avec le temps maximal en millisecondes pendant lequel le serveur attendra un nouveau message (valeur fournie à la fonction CreateMailProcess).
• La valeur de retour est un booléen indiquant si la fonction s'est terminée correctement ou si une erreur est survenue. En cas d'erreur, consultez GetLastError pour plus d'information sur celle-ci.

3.3. SetMailslotInfo

          function SetMailslotInfo(hMailslot: THandle; lReadTimeout: DWORD): BOOL; stdcall;

• hMailslot : le handle obtenu par l'appel à CreateMailslot.
• lReadTimeout : entier dont la valeur correspond au temps maximal en millisecondes pendant lequel le serveur attendra un nouveau message.
• La valeur de retour est un booléen indiquant si la fonction s'est terminée correctement ou si une erreur est survenue. En cas d'erreur, consultez GetLastError pour plus d'information sur celle-ci.

• CloseHandle,
• DuplicateHandle,
• ReadFile et ReadFileEx,
• GetFileTime,
• SetFileTime,
• GetHandleInformation,
• SetHandleInformation.

• CloseHandle,
• CreateFile,
• DuplicateHandle,
• WriteFile et WriteFileEx.

4. Utilisation en Delphi

4.1. Un exemple simple

4.1.1. Le serveur

        FHandle: THandle;

      FHandle:= CreateMailslot('\\.\mailslot\ExempleSimple', 0,
        MAILSLOT_WAIT_FOREVER, nil);

      CloseHandle(FHandle);

    var
      lpNextSize, lpMessageCount, lpNumberOfBytesRead: Cardinal;
      buffer: string;
    begin
      if GetMailslotInfo(FHandle, nil, lpNextSize, @lpMessagecount, nil) and
        (lpMessageCount > 0) then
      begin
        SetLength(buffer, lpNextSize);
        if ReadFile(FHandle, buffer[1], lpNextSize, lpNumberOfBytesRead, nil) then
          mmMessages.Lines.Add(buffer);
      end;
    end;

    unit ServeurFrm;

    interface

    uses
      Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
      Dialogs, StdCtrls;

    type
      TForm1 = class(TForm)
        mmMessages: TMemo;
        btnLire: TButton;
        procedure FormCreate(Sender: TObject);
        procedure FormDestroy(Sender: TObject);
        procedure btnLireClick(Sender: TObject);
      private
        { Private declarations }
        FHandle: THandle;
      public
        { Public declarations }
      end;
    
    var
      Form1: TForm1;
    
    implementation
    
    {$R *.dfm}
    
    procedure TForm1.FormCreate(Sender: TObject);
    begin
      FHandle:= CreateMailslot('\\.\mailslot\ExempleSimple', 0,
        MAILSLOT_WAIT_FOREVER, nil);
    end;
    
    procedure TForm1.FormDestroy(Sender: TObject);
    begin
      CloseHandle(FHandle);
    end;

    procedure TForm1.btnLireClick(Sender: TObject);
    var
      lpNextSize, lpMessageCount, lpNumberOfBytesRead: Cardinal;
      buffer: string;
    begin
      if GetMailslotInfo(FHandle, nil, lpNextSize, @lpMessagecount, nil) and
        (lpMessageCount > 0) then
      begin
        SetLength(buffer, lpNextSize);
        if ReadFile(FHandle, buffer[1], lpNextSize, lpNumberOfBytesRead, nil) then
          mmMessages.Lines.Add(buffer);
      end;
    end;
    
    end.

• A la création de la fenêtre, nous créons un mailslot dont nous conservons le handle.
• Lors d'un appui sur le bouton, nous regardons si des messages sont disponibles et si c'est le cas, nous lisons un message et le copions dans le TMemo.
  
• A la destruction de la fenêtre, nous libérons le handle du mailslot, ce qui a pour effet de fermer le mailslot et de le supprimer (ainsi que les messages qu'il pourrait contenir).

4.1.2. Le client

var
  FHandle: THandle;
  buffer: PChar;
  lpNumberOfBytesWritten: Cardinal;
begin
  FHandle:= CreateFile('\\.\mailslot\ExempleSimple', GENERIC_WRITE,
    FILE_SHARE_READ, nil, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, 0);
  if FHandle = INVALID_HANDLE_VALUE then
    raise Exception.Create(SysErrorMessage(GetLastError))
  else
  begin
    buffer:= PChar(mmMessage.Lines.Text);
    WriteFile(FHandle, buffer^, Length(buffer),
      lpNumberOfBytesWritten, nil);
    CloseHandle(FHandle);
  end;
end;

• Comme vous pouvez le constater, nous commençons par tenter d'ouvrir le mailslot. Si ce n'est pas possible, la valeur du handle contient la valeur de la constante INVALID_HANDLE_VALUE. Dans ce cas, nous affichons la raison de l'erreur en utilisant les fonctions GetlastError (qui retourne le numéro de la dernière erreur) et SysErrorMessage qui affiche le message correspondant à l'erreur.
• Si tout c'est bien passé, nous écrivons le contenu du TMemo dans le mailslot, en passant par une variable temporaire pour éviter un message d'erreur du compilateur en raison de la forme de la déclaration de la fonction. Nous terminons en fermant le mailslot par un appel à CloseHandle.

4.2. Allons plus loin

unit Mailslots;

interface
uses
  Classes, Windows;

type
  TMailslotCommon = class
  private
    FMailslotName: string;
    procedure SetMailslotName(const Value: string);
    function GetConnected: boolean;
    procedure SetConnected(const Value: boolean);
    procedure SetLocation(const Value: string);
  protected
    FMSHandle: THandle;
    FLocation: string;

    procedure RaiseError(Msg: string = '');

    property Location: string read FLocation write SetLocation;
  public
    constructor Create; virtual;
    destructor Destroy; override;

    function Connect: boolean; virtual; abstract;
    procedure Disconnect; virtual;
    function GetMailslotAddress: string;

    property Connected: boolean read GetConnected write SetConnected;
    property MailslotName: string read FMailslotName write SetMailslotName;
  end;

  TMailslotServer = class(TMailslotCommon)
  public
    function Connect: boolean; override;
    function MessageCount: Cardinal;
    function NextMessageSize: Cardinal;
    procedure ReadBuffer(var Buffer; BufferSize: Cardinal);
    procedure ReadStream(AStream: TStream);
    function ReadString: string;
  end;

  TMailslotClient = class(TMailslotCommon)
  public
    function Connect: boolean; override;
    procedure WriteBuffer(const Buffer; BufferSize: Cardinal);
    procedure WriteStream(AStream: TStream);
    procedure WriteString(AString: string);

    property Location; // rendu accessible pour le client uniquement
  end;

• Le client propose les propriétés Location et MailslotName qui correspondent aux parties variables de l'adresse du mailslot. L'adresse complète peut être connue en consultant la propriété MailslotAddress qui en assemble les différentes parties :
  \\propriété Location\mailslot\propriété MailslotName
• Le serveur ne propose pas de propriété Location car cela n'a pas de sens puisque nous avons vu qu'un processus ne peut créer que des mailslots locaux.
• Les méthodes Connect et Disconnect devront être appelées pour créer/ouvrir le mailslot et pour le refermer. La propriété Connected permet de savoir si le mailslot est ouvert.
• Les méthodes Writexxx et Readxxx permettent d'utiliser le mailslot avec un buffer, un flux de données (TStream) ou une simple chaîne de caractères.

5. Liens

• Voici un lien vers la description des mailslots disponible sur le site Microsoft Developer Network (MSDN) : Platform SDK: Interprocess Communications : Mailslots
• Le projet de démonstration incluant l'unité mailslots.pas (Delphi 7) : DelphiMailslots.zip

Articles

Delphi 2005 : Découvrez le futur Delphi 2005

DirectX : Introduction à DirectX 9 en Delphi

Variables d'environnement : Présentation, description et utilisation des variables d'environnement sous Windows

Mailslots : Présentation des mailslots et de leur utilisation en Delphi pour la communication inter-processus

Projets complets avec sources

NumericalParser : Parser numérique en Delphi afin de transformer une chaîne de caractères en valeur flottante ou entière.

RegSearch : Composant de recherche dans la base de registre

CDAReader : Lecture des informations contenues dans les fichier CDA de Windows

ScreenSaverPreview : Composant d'affichage de l'aperçu des économiseurs d'écran de Windows

ScanResources : Programme d'exploration des ressources des programmes ou des dll d'un répertoire

ClipboardViewer : Démonstration de la détection des modifications et de l'affichage du contenu du presse-papier

Matrix : Tentative de reproduction en Delphi de l'animation bien connue du film Matrix

Sources et exemples

EMFTransform : Transformation (rotation, inversion, miroir) d'un metafile Windows en mémoire

DeleteKeyTree : Suppression récursive d'un clé de la base de registre

MultiStrings : Routines de gestion de tableaux de chaînes C

GetDllFilename : Pour récupérer le chemin d'une dll par son handle

Extension du shell : Exemple d'extension du menu contextuel du shell de Windows

TriStringGrid : Exemple de tri par colonne d'un composant TStringGrid à l'aide d'un algorithme de tri rapide (quick sort)

XPManifestCPL : Utilisation des contrôles XP dans une application du panneau de configuration (cpl)

Bouboules : Modélisation à l'aide du design pattern Observer

Divers

Diagramme ternaire : Un logiciel gratuit de tracé de diagramme ternaire